Einbau Tutorials

[Holz]

11. Käufliche Powerups (Insta Kill, Max Ammo, Double Points)

Erstelle Dir in Mods/Mapname/Maps eine buy_powerup.gsc mit folgendem Inhalt:

Code:

#include common_scripts\utility;
#include maps\_zombiemode_utility;
#include maps\_utility;
 
main()
{
   powerup_trigs = getentarray( "buy_powerup", "targetname" );
   array_thread( powerup_trigs,::buy_powerup );
}
 
buy_powerup()
{
   while(1)
   {
      player = undefined;
      powerup_name = undefined;
      cost = 1000;
      powerup = self.script_noteworthy;
 
      self UseTriggerRequireLookAt();
 
      if( powerup == "insta_kill" )
      {
         powerup_name = "Insta Kill";
         cost = 2000;
      }
      else if( powerup == "double_points" )
      {
         powerup_name = "Double Points";
         cost = 1000;
      }
      else if( powerup == "max_ammo" )
      {
         powerup_name = "Max Ammo";
         cost = 1000;
      }
   
      self SetHintString( "Press &&1 to buy  " + powerup_name + " Powerup [Cost: "+cost+"]" );
      self waittill( "trigger", player );
 
      if( !is_player_valid( player ) )
      {
         continue;
      }
 
      if( player.score >= cost )
      {
         player playsound( "cha_ching" );
         player maps\_zombiemode_score::minus_to_player_score( cost );
 
         if( powerup == "insta_kill" )
         {
            maps\_zombiemode_powerups::insta_kill_powerup();
         }
         else if( powerup == "double_points" )
         {
            maps\_zombiemode_powerups::double_points_powerup();
         }
         else if( powerup == "max_ammo" )
         {
            maps\_zombiemode_powerups::full_ammo_powerup();
         }
      }
      else
      {
         player playsound( "no_cha_ching" );
      }
      wait(30);
   }
}

 
Geh in Deine /mods/maps/mapname.gsc und füge unter maps\_zombiemode::main();

Code:

maps\buy_powerup::main();

ein.
 
Dann mach dir im Radiant einen Trigger Use mit den KVP's

Code:

script_noteworthy :  max_ammo (oder insta_kill, oder double_points)
targetname : buy_powerup

Nun nur noch beim Mod builden nicht vergessen die buy_powerup.gsc anzuhaken.
ZM Tut - buyable Powerups
Vorsicht Bug beim Link!!!